@ECHO OFF



REM Edit file path to where DCS_updater.exe is.
CD "C:\Program Files\Eagle Dynamics\DCS World OpenBeta\bin"

REM Copyright 2019 Paul Meckel
REM 
REM Permission is hereby granted, free of charge, to any person obtaining
REM a copy of this software and associated documentation files (the "Software"),
REM to deal in the Software without restriction, including without limitation
REM the rights to use, copy, modify, merge, publish, distribute, sublicense,
REM and/or sell copies of the Software, and to permit persons to whom the
REM Software is furnished to do so, subject to the following conditions:
REM 
REM The above copyright notice and this permission notice shall be
REM included in all copies or substantial portions of the Software.
REM 
REM THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
REM IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
REM FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
REM AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
REM WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
REM CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

:MENU
CLS
ECHO.
ECHO ************************************************************
ECHO *                                                          *
ECHO *              DCS - World OpenBeta Launcher               *
ECHO *                                                          *
ECHO ************************************************************
ECHO *                                                          *
ECHO * 1 - Launch                                               *
ECHO * 2 - Update                                               *
ECHO * 3 - Repair                                               *
ECHO * 4 - Version                                              *
ECHO * 5 - Modules (Depreciated, use Module Manager)            *
ECHO * 6 - Custom Command                                       *
ECHO * 9 - Exit                                                 *
ECHO *                                                          *
ECHO ************************************************************
ECHO.
SET /P SELECTION=Select and press ENTER: 
IF %SELECTION%==1 GOTO LAUNCH
IF %SELECTION%==2 GOTO UPDATE
IF %SELECTION%==3 GOTO REPAIR
IF %SELECTION%==4 GOTO VERSIONMENU
IF %SELECTION%==5 GOTO MODULES
IF %SELECTION%==6 GOTO CUSTOM
IF %SELECTION%==9 GOTO END
GOTO MENU

:LAUNCH
ECHO Lauching . . .
START DCS_updater.exe
PAUSE
GOTO MENU

:UPDATE
ECHO Updating . . .
START DCS_updater.exe update
PAUSE
GOTO MENU

:REPAIR
ECHO Repairing . . .
START DCS_updater.exe repair
PAUSE
GOTO MENU

:VERSIONMENU
CLS
ECHO.
ECHO ************************************************************
ECHO *                                                          *
ECHO *              DCS - World OpenBeta Launcher               *
ECHO *                     Select Version                       *
ECHO *                                                          *
ECHO ************************************************************
ECHO *                                                          *
ECHO * 1 - Switch branch                                        *
ECHO * 2 - Get specific version                                 *
ECHO * 3 - Main menu                                            *
ECHO *                                                          *
ECHO ************************************************************
ECHO.
SET /P SELECTION=Select and press ENTER: 
IF %SELECTION%==1 GOTO BRANCHMENU
IF %SELECTION%==2 GOTO ENTERVERSION
IF %SELECTION%==3 GOTO MENU
GOTO VERSIONMENU

:BRANCHMENU
CLS
ECHO.
ECHO ************************************************************
ECHO *                                                          *
ECHO *              DCS - World OpenBeta Launcher               *
ECHO *                     Select Branch                        *
ECHO *                                                          *
ECHO ************************************************************
ECHO *                                                          *
ECHO * 1 - Release (Stable)                                     *
ECHO * 2 - OpenBeta                                             *
ECHO * 3 - OpenAlpha                                            *
ECHO * 9 - Back                                                 *
ECHO *                                                          *
ECHO ************************************************************
ECHO.
SET /P SELECTION=Select and press ENTER: 
IF %SELECTION%==1 START DCS_updater update @release
IF %SELECTION%==2 START DCS_updater update @openbeta
IF %SELECTION%==3 START DCS_updater update @openalpha
IF %SELECTION%==9 GOTO VERSIONMENU
GOTO BRANCHMENU

:ENTERVERSION
ECHO.
ECHO Selecting specific version.
ECHO.
ECHO Refer to https://forums.eagle.ru/showthread.php?t=114030
ECHO for specific version numbers.
ECHO.
ECHO Enter the Version you want to get in one of the formats:
ECHO - ^<MainVersion^>, for example: 2.5.4
ECHO - ^<MainVersion^>.^<SubVersion^>, for example 2.5.4.25729
ECHO - ^<MainVersion^>.^<SubVersion^>@^<Branch^>, for example 2.5.4.25729@openbeta
ECHO - @^<Branch^>, for example @openbeta
ECHO - Enter 0 to go back
ECHO.
SET /P VERSIONINPUT=Enter Version: 
IF %VERSIONINPUT%==0 GOTO VERSIONMENU
ECHO.
ECHO Fetching %VERSIONINPUT%
ECHO.
ECHO DCS_updater.exe update %VERSIONINPUT%
START DCS_updater.exe update %VERSIONINPUT%
PAUSE
GOTO VERSIONMENU

:MODULES
CLS
ECHO.
ECHO Installing and removing modules.
ECHO Install only modules you actually own,
ECHO or DCS will bug you for an activation every time.
ECHO.
ECHO DEPRECIATED. USE MODULE MANAGER IN DCS IF POSSIBLE
ECHO.
ECHO Select one:
ECHO 1 - Install Modules
ECHO 2 - Uninstall Modules
ECHO 9 - Back
SET /P SELECTION=Select and press ENTER: 
IF %SELECTION%==1 GOTO MODULES_INSTALL
IF %SELECTION%==2 GOTO MODULES_UNINSTALL
IF %SELECTION%==9 GOTO MENU
GOTO MODULES

:MODULES_INSTALL
SET UPDATER_CMD=install
GOTO MODULES_INPUT
:MODULES_UNINSTALL
SET UPDATER_CMD=uninstall
GOTO MODULES_INPUT
:MODULES_INPUT
ECHO.
ECHO Enter a list of modules you wish to %UPDATER_CMD%, seperated by spaces
ECHO For example "A-10C F-86F FC3", without quotation marks
ECHO Enter 0 to go back.
SET /P SELECTION=Enter module list and press ENTER: 
IF %SELECTION%==0 GOTO MODULES
ECHO DCS_updater %UPDATER_CMD% %SELECTION%
START DCS_updater %UPDATER_CMD% %SELECTION%
PAUSE
GOTO MODULES

:CUSTOM
ECHO.
ECHO Anything you enter here will be put as arguments to DCS_updater.exe
ECHO For example entering "foo bar" will execute
ECHO DCS_updater.exe foo bar
ECHO.
ECHO DCS_updater.exe %UPDATER_CMD%
START DCS_updater.exe %UPDATER_CMD%
PAUSE
GOTO MENU

:END
ECHO Bye